MLIR is a unifying software framework for compiler development.^[1] MLIR can make optimal use of a variety of computing platforms such as GPUs, DPUs, TPUs, FPGAs, AI ASICS, and quantum computing systems (QPUs).^[2]

MLIR is a sub-project of the LLVM Compiler Infrastructure project and aims to build a "reusable and extensible compiler infrastructure (..) and aid in connecting existing compilers together."^[3][4][5]

The name of the project stands for Multi-Level Intermediate Representation, in which the multi-level keyword refers to the possibility of defining multiple dialects and progressive conversions towards machine code. This capability enables MLIR to retain information at a higher level of abstraction and perform more accurate analyses and transformations, which otherwise would have to deal with lower level representations.^[6]

Operations represent the core element around which dialects are built. They are identified by a name – that must be unique within the dialect they belong to – and have optional operands, results, attributes and regions. Operands and results adhere to the Static Single Assignment form. Each result also has an associated type. Attributes represent compile-time knowledge (e.g., constant values). Regions consist in a list of blocks, each of which may have input arguments and contain a list of operations.^[7] Despite the dialects being designed around the SSA form, PHI nodes are not part of this design and are instead replaced by the input arguments of blocks, in combination with operands of control-flow operations.^[8]

The general syntax for an operation is the following:

%res:2 = "mydialect.morph"(%input#3) ({
            ^bb0(%arg0: !mydialect<"custom_type"> loc("mysource.cc":10:8)):
                // nested operations
         }) { some.attribute = true, other_attribute = 1.5 }
         : (!mydialect<"custom_type">) -> (!mydialect<"other_type">, !mydialect<"other_type">)
         loc(callsite("foo" at "mysource.cc":10:8))

The example shows an operation that is named morph, belongs to the mydialect dialect, takes one input operand and produces two results. The input argument has an associated type named custom_type and the results both have type other_type, with both the types belonging again to the mydialect dialect. The operation also has two associated attributes – named some.attribute and other_attribute – and a region containing one block. Finally, with keyword loc a locations are attached for debugging purposes.^[9]

The syntax of operations, types and attributes can also be customized according to the user preferences by implementing proper parsing and printing functions within the operation definition.^[10]

func.func @matrix_add(%arg0: memref<10x20xf32>, %arg1: memref<10x20xf32>) -> memref<10x20xf32> {
    %result = memref.alloc() : memref<10x20xf32>

	affine.for %i = 0 to 10 {
		affine.for %j = 0 to 20 {
			%lhs = memref.load %arg0[%i, %j] : memref<10x20xf32>
			%rhs = memref.load %arg1[%i, %j] : memref<10x20xf32>
			%sum = arith.addf %lhs, %rhs : f32
			memref.store %sum, %result[%i, %j] : memref<10x20xf32>
		}
	}
    
    func.return %result : memref<10x20xf32>
}

The operations of a dialect can be defined using the C++ language, but also in a more convenient and robust way by using the Operation definition specification (ODS).^[13] By using TableGen, the C++ code for declarations and definitions can be then automatically generated.^[14]

The autogenerated code can include parsing and printing methods – which are based on a simple string mapping the structure of desired textual representation – together with all the boilerplate code for accessing fields and perform common actions such verification of the semantics of each operation, canonicalization or folding.^[15]

The same declaration mechanism can be used also for types and attributes, which are the other two categories of elements constituting a dialect.^[15]

The following example illustrates how to specify the assembly format of an operation expecting a variadic number of operands and producing zero results. The textual representation consists in the optional list of attributes, followed by the optional list of operands, a colon, and types of the operands.^[13]

let assemblyFormat = "attr-dict ($operands^ `:` type($operands))?";

Transformations can always be performed directly on the IR, without having to rely on built-in coordination mechanisms. However, in order to ease both implementation and maintenance, MLIR provides an infrastructure for IR rewriting that is composed by different rewrite drivers. Each driver receives a set of objects named patterns, each of which has its own internal logic to match operations with certain properties. When an operation is matched, the rewrite process is performed and the IR is modified according to the logic within the pattern.^[16]

#map = affine_map<(d0, d1) -> (d0, d1)>

module {
    func.func @avg(%arg0: memref<10x20xf32>, %arg1: memref<10x20xf32>) -> memref<10x20xf32> {
        %alloc = memref.alloc() : memref<10x20xf32>
        %c0 = arith.constant 0 : index
        %c10 = arith.constant 10 : index
        %c1 = arith.constant 1 : index
        
        scf.for %arg2 = %c0 to %c10 step %c1 {
            %c0_0 = arith.constant 0 : index
            %c20 = arith.constant 20 : index
            %c1_1 = arith.constant 1 : index
            
            scf.for %arg3 = %c0_0 to %c20 step %c1_1 {
                %0 = memref.load %arg0[%arg2, %arg3] : memref<10x20xf32>
                %1 = memref.load %arg1[%arg2, %arg3] : memref<10x20xf32>
                %2 = arith.addf %0, %1 : f32
                memref.store %2, %alloc[%arg2, %arg3] : memref<10x20xf32>
            }
        }
        
        return %alloc : memref<10x20xf32>
    }
}

#map = affine_map<(d0, d1) -> (d0, d1)>

module {
    func.func @avg(%arg0: memref<10x20xf32>, %arg1: memref<10x20xf32>) -> memref<10x20xf32> {
        %alloc = memref.alloc() : memref<10x20xf32>
        %c0 = arith.constant 0 : index
        %c10 = arith.constant 10 : index
        %0 = arith.subi %c10, %c0 : index
        %c1 = arith.constant 1 : index
        %c0_0 = arith.constant 0 : index
        %c20 = arith.constant 20 : index
        %1 = arith.subi %c20, %c0_0 : index
        %c1_1 = arith.constant 1 : index
        %c1_2 = arith.constant 1 : index
        
        gpu.launch blocks(%arg2, %arg3, %arg4) in (%arg8 = %0, %arg9 = %c1_2, %arg10 = %c1_2) threads(%arg5, %arg6, %arg7) in (%arg11 = %1, %arg12 = %c1_2, %arg13 = %c1_2) {
            %2 = arith.addi %c0, %arg2 : index
            %3 = arith.addi %c0_0, %arg5 : index
            %4 = memref.load %arg0[%2, %3] : memref<10x20xf32>
            %5 = memref.load %arg1[%2, %3] : memref<10x20xf32>
            %6 = arith.addf %4, %5 : f32
            memref.store %4, %alloc[%2, %3] : memref<10x20xf32>
            gpu.terminator
        }
        
        return %alloc : memref<10x20xf32>
    }
}

MLIR allows to apply existing optimizations (e.g., common subexpression elimination, loop-invariant code motion) on custom dialects by means of traits and interfaces. These two mechanisms enable transformation passes to operate on operations without knowing their actual implementation, relying only on some properties that traits or interfaces provide.^[18][19]

Traits are meant to be attached to operations without requiring any additional implementation. Their purpose is to indicate that the operation satisfies certain properties (e.g. having exactly two operands).^[18] Interfaces, instead, represent a more powerful tool through which the operation can be queried about some specific aspect, whose value may change between instances of the same kind of operation. An example of interface is the representation of memory effects: each operation that operates on memory may have such interface attached, but the actual effects may depend on the actual operands (e.g., a function call with arguments possibly being constants or references to memory).^[19]

The freedom in modeling intermediate representations enables MLIR to be used in a wide range of scenarios. This includes traditional programming languages,^[20] but also high-level synthesis,^[21][22] quantum computing^[23] and homomorphic encryption.^[24][25][26] Machine learning applications also take advantage of built-in polyhedral compilation techniques, together with dialects targeting accelerators and other heterogeneous systems.^{[27][28][29][30][31]}

• TensorFlow
• Tensor Processing Unit